RIGHT_HALF   equ 1
BOTTOM_HALF  equ 0
BOTTOM_RIGHT equ 0

        org $1001-2
        dw  $1001

        dw nextln, 2018 ; second word is line number
        db $9E
        if start > 9999
        db "0"+start/10000
        endif
        db "0"+(start/1000)%10,"0"+(start/100)%10,"0"+(start/10)%10,"0"+start%10,0
nextln  db 0,0

start
        sei
        ldx     #0
        ldy     #4
loop
src     
        lda     $d000,x
        if RIGHT_HALF && !BOTTOM_RIGHT
        eor     #$0f
        endif
        if BOTTOM_HALF && !BOTTOM_RIGHT
        pha
        stx     xsavebh+1
        txa
        and     #4
        bne     skip
        lda     #0
        db $2c
skip
        lda     #$ff
        sta     eorer+1
        pla
eorer
        eor     #0
xsavebh
        ldx     #0
        endif
        if BOTTOM_RIGHT && !RIGHT_HALF && !BOTTOM_HALF
        pha
        stx     xsavebr+1
        txa
        and     #7
        tax
        pla
        eor     table,x
xsavebr
        ldx     #0
        endif
dest    
        sta     $3800,x
        txa
        sta     $e08,x
        inx
        bne     loop

        inc     src+2
        inc     dest+2
        dey
        bne     loop

        lda     $ff12
        and     #%11111011
        sta     $ff12
        lda     #$38
        sta     $ff13

        lda     #$2b
        sta     $314
        
        txa
        ldy     #7
spaceclr
        sta     $3900,y
        dey
        bpl     spaceclr

        cli
        rts

        if BOTTOM_RIGHT && !RIGHT_HALF && !BOTTOM_HALF
table   db 0, 1, 3, 7, 15, 31, 63, 127
        endif

        if *-$1001>126
        Length constraint error.
        endif